如何完全地确保图像大小的固定，不受坐标标签以及坐标轴变化而变化？

Question

明明ImageSize已经给定了图像的大小，可是绘制的图像大小依然受坐标轴，坐标标签等的影响。

在已经留下足够空位的情况下如何确保输出图像的大小的稳定？使用的函数是Graphics。

Answer 1

ImageSize是控制整个图像的大小，当坐标轴的标签变大时，由于整个图像大小一定了，那么里面图自然就变小了，见例一。

如果想要，当坐标轴的标签变大时，里面的图像不变小，可以使用ImagePadding，见例二。

例一：

Column[Table[
  Graphics[{Thick, Green, Rectangle[{0, -1}, {2, 1}], Red, Disk[], 
    Blue, Circle[{2, 0}], Yellow, Polygon[{{2, 0}, {4, 1}, {4, -1}}], 
    Purple, Arrowheads[Large], Arrow[{{4, 3/2}, {0, 3/2}, {0, 0}}], 
    Black, Dashed, Line[{{-1, 0}, {4, 0}}]}, Axes -> True, 
   AxesLabel -> {Style["xxx", k], Style["yyy", k]}, 
   ImageSize -> {500, Automatic}, Background -> Black], {k, 10, 50, 
   20}]]

 

例二：

Column[Table[
  Graphics[{Thick, Green, Rectangle[{0, -1}, {2, 1}], Red, Disk[], 
    Blue, Circle[{2, 0}], Yellow, Polygon[{{2, 0}, {4, 1}, {4, -1}}], 
    Purple, Arrowheads[Large], Arrow[{{4, 3/2}, {0, 3/2}, {0, 0}}], 
    Black, Dashed, Line[{{-1, 0}, {4, 0}}]}, Axes -> True, 
   AxesLabel -> {Style["xxx", k], Style["yyy", k]}, 
   ImagePadding -> 50, ImageSize -> {600, Automatic}, 
   Background -> Black], {k, 10, 50, 20}]]

例二中的ImageSize也是控制整个图像的大小，但通过ImagePadding指定了里面图像到边界的距离（即留给标签的空白宽度），这样里面图像的大小就固定了，但因此标签可能会被剪裁。

ImagePadding可以四面都设置，详见帮助。