Manipulate里的Button，为什么不能用Table?

Question

Clear["Global`*"]
Manipulate[
 Grid[{
   Table[Graphics[{If[EvenQ[a[[i]]], Red, Black], 
      Rectangle[{0, i}]}], {i, 15}],
   Table[Button["p" <> ToString[i], ++a[[i]]], {i, 15}]
   }]
 , {n, 8, 15, 1}, Initialization :> {a = Table[0, {i, 15}]}, 
 SaveDefinitions -> True]

如果去掉Table,一个一个的是可以的，比如

Clear["Global`*"]
Manipulate[
 Grid[{
   Table[Graphics[{If[EvenQ[a[[i]]], Red, Black], 
      Rectangle[{0, i}]}], {i, 15}],
   {Button["p" <> ToString[1], ++a[[1]]]}
   }]
 , {n, 8, 15, 1}, Initialization :> {a = Table[0, {i, 15}]}, 
 SaveDefinitions -> True]

 

为啥呢?

Answer 1

问题在于 Button 的第二个参数，（帮助中说“将 action 保持在未操作状态”），需要注意的是此处的i不是Table中的i。

一种解决方案如下（即，在生成Button后，再对其修改）：

Clear["Global`*"]
Manipulate[
 Grid[{Table[
    Graphics[{If[EvenQ[a[[i]]], Red, Black], Rectangle[{0, i}]}], {i, 
     15}], Table[
    Button["p" <> ToString[i], ++a[[ii]]] /. ii -> i, {i, 15}]}], {n, 
  8, 15, 1}, Initialization :> {a = Table[0, {i, 15}]}, 
 SaveDefinitions -> True]

 

Comments

感谢，说到了问题的本质

Answer 2

Clear["Global`*"]
Manipulate[
 Grid[{Table[
    Graphics[{If[EvenQ[a[[i]]], Red, Black], Rectangle[{0, i}]}], {i, 
     15}], Button["p" <> ToString[#], ++a[[#]]] & /@ Range[15]}], 
 Initialization :> {a = Table[0, {i, 15}]}, SaveDefinitions -> True]

 

Answer 3

不用Button，不过效果近似

Row@Table[
DynamicModule[{c=1},
EventHandler[
Graphics[{Dynamic@If[c==1,Red,Black],Rectangle[]},ImageSize->Tiny,PlotLabel->i],
"MouseClicked":>(c=1-c)]],{i,15}]

 

Comments

谢谢！这得好好学学！