矩阵的循环相乘有直接的命令吗？

Question

数的循环相乘有命令， 如Product[x+i,{i,1,3}]得到(x+1)(x+2)(x+3)。 我想要一个结果如a.b.a.b^2.a.b^3.......的矩阵连乘，有直接的命令吗？如果没有怎样写成一个函数？得到f(m)=:a.b.a.b^2.........a.b^m。请大侠们帮忙啊！！！

Answer 1

f[a_, b_, m_] := Dot @@ Flatten[Table[{a, b^i}, {i, m}]]

涉及到的函数，Table，Flatten，Apply，Dot。

Answer 2

如果矩阵较大的话可以试试

f[a_, b_, m_] :=
 Nest[{x = First@#.b, Last@#.x} &, {#, #} &[a.b], m - 1] // Last

能少算几次乘法

Comments

按道理少算几次乘法运算用时会快点，但是在mma里面这种算法没有@苹果的算法快呢，其中发生了什么。。。

---

看看你的测试数据和结果比较

---

No.1 大m
a = {{1., 0.}, {0., 1.}}; b = {{2., 0.}, {0., 1.}};
f1[a_, b_, m_] := Dot @@ Flatten[Table[{a, b^i}, {i, m}]];
f2[a_, b_, m_] :=
  Nest[{x = First@#.b, Last@#.x} &, {#, #} &[a.b], m - 1] // Last;
f1[a, b, 10000]; // AbsoluteTiming
f2[a, b, 10000]; // AbsoluteTiming
{0.051003, Null}
{0.100006, Null}

No.2 大矩阵
a = IdentityMatrix[100]; b = DiagonalMatrix[Range[100]];
f1[a_, b_, m_] := Dot @@ Flatten[Table[{a, b^i}, {i, m}]];
f2[a_, b_, m_] :=
  Nest[{x = First@#.b, Last@#.x} &, {#, #} &[a.b], m - 1] // Last;
f1[a, b, 500]; // AbsoluteTiming
f2[a, b, 500]; // AbsoluteTiming
{0.874050, Null}
{7.368421, Null}

---

你有比较过两者结果相等没？

---

谢谢，确实@苹果的答案有点问题啊，而且即便改成Dot @@ Flatten[Table[{a, b^i}, {i, m}],1]的话还是不行啊，矩阵的n次方在mma里不是矩阵^n，mma里的矩阵^n是矩阵各元素的n次方，进一步改正@苹果的答案为Dot @@ Flatten[Table[{a, MatrixPower[b, i]}, {i, m}], 1]。

这样就合乎道理了，计算次数少的用时少。
No.1 大m
a = {{1., 0.}, {0., 1.}}; b = {{2., 0.}, {0., 1.}};
f1[a_, b_, m_] :=
  Dot @@ Flatten[Table[{a, MatrixPower[b, i]}, {i, m}], 1];
f2[a_, b_, m_] :=
  Nest[{x = First@#.b, Last@#.x} &, {#, #} &[a.b], m - 1] // Last;
ans1 = f1[a, b, 2000]; // AbsoluteTiming
ans2 = f2[a, b, 2000]; // AbsoluteTiming
Norm[ans1 - ans2]
{0.150008, Null}
{0.019001, Null}
0.

No.2 大矩阵
a = IdentityMatrix[100]; b = DiagonalMatrix[Range[100]];
f1[a_, b_, m_] :=
  Dot @@ Flatten[Table[{a, MatrixPower[b, i]}, {i, m}], 1];
f2[a_, b_, m_] :=
  Nest[{x = First@#.b, Last@#.x} &, {#, #} &[a.b], m - 1] // Last;
ans1 = f1[a, b, 200]; // AbsoluteTiming
ans2 = f2[a, b, 200]; // AbsoluteTiming
Norm[ans1 - ans2]
{7.696440, Null}
{1.705098, Null}
0