怎么提高图形显示效果？

Question

\[Delta] = 0.7;
F[x_] := 2*\[Alpha]*(-1/8*x^-8 + 1/5*x^-5 - 1/2*x^-2 - 
      1/3*Log[x + 1] + 1/6*Log[(x - 1/2)^2 + 3/4] - 
      Sqrt[3]/3*ArcTan[(2*Sqrt[3]*(x - 1/2))/3]) + (1 - 
      2*\[Alpha])*(-1/4*x^-4 + x^-1 - 1/3*Log[x + 1] + 
      1/6*Log[(x - 1/2)^2 + 3/4] + 
      Sqrt[3]/3*ArcTan[(2*Sqrt[3]*(x - 1/2))/3]) - (-1/3*Log[x + 1] + 
     1/6*Log[(x - 1/2)^2 + 3/4] + 
     Sqrt[3]/3*ArcTan[(2*Sqrt[3]*(x - 1/2))/3]);
t2 = ContourPlot[
  F[((1 - \[Delta]^3 + m^3)/\[Delta]^3)^(1/3)] - F[m] == 0, {\[Alpha],
    0, 10}, {m, 0.7, 1}, FrameLabel -> {\[Alpha], m}]

结果图

MMA默认图形显示效果很差，看上去很模糊

Q1 怎么提高绘图默认分辨率，让图形看上去更精致一些，能想MATLAB一样的效果吗？

Q2  在正式论文里引用图像时该怎么处理（总感觉截图的话不太好），得到想要的大小和分辨率？

Q3  纵坐标标签 m 能调正吗？

Answer 1

Mathematica 在图上来说是很给力的。

下面是一些常用的参数设置以及相关的函数（详细说明请查询对应的帮助，在 Ｍｍａ 中按 F1 即可）：

• PlotPoints  绘图精度
• Style  文本样式
• Rotate  旋转
• FrameStyle  边框样式
• ImageResolution  导出图像时指定的分辨率，单位：ppi
• ImageSize  图像大小

例：

\[Delta] = 0.7;
F[x_, \[Alpha]_] := 
  2 \[Alpha] (-1/8 x^-8 + 1/5 x^-5 - 1/2 x^-2 - 1/3 Log[x + 1] + 
      1/6 Log[(x - 1/2)^2 + 3/4] - 
      Sqrt[3]/3 ArcTan[(2 Sqrt[3] (x - 1/2))/3]) + (1 - 
      2 \[Alpha]) (-1/4 x^-4 + x^-1 - 1/3 Log[x + 1] + 
      1/6 Log[(x - 1/2)^2 + 3/4] + 
      Sqrt[3]/3 ArcTan[(2 Sqrt[3] (x - 1/2))/3]) - (-1/3 Log[x + 1] + 
     1/6 Log[(x - 1/2)^2 + 3/4] + 
     Sqrt[3]/3 ArcTan[(2 Sqrt[3] (x - 1/2))/3]);
t2 = ContourPlot[
  F[((1 - \[Delta]^3 + m^3)/\[Delta]^3)^(1/3), \[Alpha]] - 
    F[m, \[Alpha]] == 0,
  {\[Alpha], 0, 10},
  {m, 0.7, 1},
  FrameLabel -> {Style["\[Alpha]", Bold, 16], 
    Rotate[Style["m", Bold, 16], -Pi/2]},(*Rotate旋转*)
  FrameStyle -> Directive[12, FontFamily -> "Arial", Black],(*边框样式*)
  Background -> White,
  PlotPoints -> 50,(*绘图精度，50已经是比较大的值了*)
  ImageSize -> {500, 500}(*图像尺寸，单位：像素*)]
Export["D:/t2.png", t2, ImageResolution -> 220]
(*ImageResolution：图像分辨率，在Word中一般为：220ppi，96ppi，72ppi，如果是打印的话就设置为220ppi\
*)

 

Comments

O(∩_∩)O谢谢！